' ***************************************
' Run Cinavia Detector on a Set of MP4s *
' Last updated by GrampaD 08-15-2020    *
'                                       *
' This script runs the CinDe detector   *
' on a set of properly prepared MP3     *
' test files and writes the results to  *
' a delimited flatfile.           *
' ALL movies released 2010 or later     *
' should be checked for the Cinavia     *
' watermark.                            *
' https://en.wikipedia.org/wiki/Cinavia *
' ***************************************

VbDQ = chr(34)
VbDelimiter = ","

strHome = "C:\Programs\Media\cinde\"
strFolder = "temp\"
strExecString = ""
strCounter = 0

Set objShell = wscript.createobject("wscript.shell")
Set objFSO = Wscript.CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strHome & strFolder)
Set objResults = objFSO.CreateTextFile(strHome & "results.txt", True)

objResults.WriteLine "ID,Name,Results"

For Each objFile In objFolder.Files
  strCounter = strCounter + 1
  objResults.Write VbDQ & strCounter & VbDQ & VbDelimiter & VbDQ & objFile.Name & VbDQ & VbDelimiter
  strExecString = "cinde -q high -i " & VbDQ & strFolder & objFile.Name & VbDQ
  Set ObjExec = objShell.Exec(strExecString)
  Do
    strCapture = ObjExec.StdOut.ReadLine()
    strFlag = Left(strCapture,2)
    Select Case strFlag
      Case "(="
        ObjResults.Write VbDQ & Lcase(strCapture) & VbDQ & VbCrLf
      Case "=("
        ObjResults.Write VbDQ & Ucase(strCapture) & VbDQ & VbCrLf
    End Select 
  Loop While Not ObjExec.Stdout.atEndOfStream
Next

msgbox "Done. " & strCounter & " files processed."